Git Repositories

I18n: Update translation sv (100%).
[thunar.git] / acinclude.m4
1 dnl Copyright (c) 2004-2006
2 dnl         The Thunar development team. All rights reserved.
3 dnl
4 dnl Written for Thunar by Benedikt Meurer <benny@xfce.org>.
5 dnl
6
7
8
9 dnl # BM_THUNAR_PLUGIN_APR()
10 dnl #
11 dnl # Check whether the "Advanced Properties" plugin
12 dnl # should be built and installed.
13 dnl #
14 AC_DEFUN([BM_THUNAR_PLUGIN_APR],
15 [
16 AC_ARG_ENABLE([apr-plugin], [AC_HELP_STRING([--disable-apr-plugin], [Don't build the thunar-apr plugin, see plugins/thunar-apr/README])],
17   [ac_bm_thunar_plugin_apr=$enableval], [ac_bm_thunar_plugin_apr=yes])
18 AC_MSG_CHECKING([whether to build the thunar-apr plugin])
19 AM_CONDITIONAL([THUNAR_PLUGIN_APR], [test x"$ac_bm_thunar_plugin_apr" = x"yes"])
20 AC_MSG_RESULT([$ac_bm_thunar_plugin_apr])
21
22 dnl Check for libexif (for the "Image" properties page)
23 XDT_CHECK_OPTIONAL_PACKAGE([EXIF], [libexif], [0.6.0], [exif], [Exif support])
24 ])
25
26
27
28 dnl # BM_THUNAR_PLUGIN_SBR()
29 dnl #
30 dnl # Check whether the "Simple Builtin Renamers" plugin
31 dnl # should be built and installed.
32 dnl #
33 AC_DEFUN([BM_THUNAR_PLUGIN_SBR],
34 [
35 AC_ARG_ENABLE([sbr-plugin], AC_HELP_STRING([--disable-sbr-plugin], [Don't build the thunar-sbr plugin, see plugins/thunar-sbr/README]),
36   [ac_bm_thunar_plugin_sbr=$enableval], [ac_bm_thunar_plugin_sbr=yes])
37 AC_MSG_CHECKING([whether to build the thunar-sbr plugin])
38 AM_CONDITIONAL([THUNAR_PLUGIN_SBR], [test x"$ac_bm_thunar_plugin_sbr" = x"yes"])
39 AC_MSG_RESULT([$ac_bm_thunar_plugin_sbr])
40
41 dnl Check for PCRE (for the "Search & Replace" renamer)
42 XDT_CHECK_OPTIONAL_PACKAGE([PCRE], [libpcre], [6.0], [pcre], [Regular expression support])
43 ])
44
45
46
47 dnl # BM_THUNAR_PLUGIN_TPA()
48 dnl #
49 dnl # Check whether the "Trash Panel Applet" plugin should
50 dnl # be built and installed (this is actually a plugin
51 dnl # for the Xfce panel, not for Thunar).
52 dnl #
53 AC_DEFUN([BM_THUNAR_PLUGIN_TPA],
54 [
55 AC_ARG_ENABLE([tpa-plugin], AC_HELP_STRING([--disable-tpa-plugin], [Don't build the thunar-tpa plugin, see plugins/thunar-tpa/README]),
56   [ac_bm_thunar_plugin_tpa=$enableval], [ac_bm_thunar_plugin_tpa=yes])
57 if test x"$ac_bm_thunar_plugin_tpa" = x"yes"; then
58   XDT_CHECK_PACKAGE([LIBXFCE4PANEL], [libxfce4panel-1.0], [4.7.0],
59   [
60     dnl # Can only build thunar-tpa if D-BUS was found previously
61     ac_bm_thunar_plugin_tpa=$DBUS_FOUND
62   ],
63   [
64     dnl # Cannot build thunar-tpa if xfce4-panel is not installed
65     ac_bm_thunar_plugin_tpa=no
66   ])
67 else
68   ac_bm_thunar_plugin_tpa=no
69 fi
70 AC_MSG_CHECKING([whether to build the thunar-tpa plugin])
71 AM_CONDITIONAL([THUNAR_PLUGIN_TPA], [test x"$ac_bm_thunar_plugin_tpa" = x"yes"])
72 AC_MSG_RESULT([$ac_bm_thunar_plugin_tpa])
73 ])
74
75
76
77 dnl # BM_THUNAR_PLUGIN_UCA()
78 dnl #
79 dnl # Check whether the "User Customizable Actions" plugin
80 dnl # should be built and installed.
81 dnl #
82 AC_DEFUN([BM_THUNAR_PLUGIN_UCA],
83 [
84 AC_ARG_ENABLE([uca-plugin], AC_HELP_STRING([--disable-uca-plugin], [Don't build the thunar-uca plugin, see plugins/thunar-uca/README]),
85   [ac_bm_thunar_plugin_uca=$enableval], [ac_bm_thunar_plugin_uca=yes])
86 AC_MSG_CHECKING([whether to build the thunar-uca plugin])
87 AM_CONDITIONAL([THUNAR_PLUGIN_UCA], [test x"$ac_bm_thunar_plugin_uca" = x"yes"])
88 AC_MSG_RESULT([$ac_bm_thunar_plugin_uca])
89 ])
90
91 dnl # BM_THUNAR_PLUGIN_WALLPAPER()
92 dnl #
93 dnl # Check whether the "Wallpaper" plugin
94 dnl # should be built and installed.
95 dnl #
96 AC_DEFUN([BM_THUNAR_PLUGIN_WALLPAPER],
97 [
98 AC_ARG_ENABLE([wallpaper-plugin], AC_HELP_STRING([--disable-wallpaper-plugin], [Don't build the thunar-wallpaper plugin, see plugins/thunar-wallpaper/README]),
99   [ac_bm_thunar_plugin_wallpaper=$enableval], [ac_bm_thunar_plugin_wallpaper=yes])
100 AC_MSG_CHECKING([whether to build the thunar-wallpaper plugin])
101 AM_CONDITIONAL([THUNAR_PLUGIN_WALLPAPER], [test x"$ac_bm_thunar_plugin_wallpaper" = x"yes"])
102 AC_MSG_RESULT([$ac_bm_thunar_plugin_wallpaper])
103 if test x"$ac_bm_thunar_plugin_wallpaper" = x"yes"; then
104         AC_CHECK_PROG([xfconf_query_found], [xfconf-query], [yes], [no])
105         if test x"$xfconf_query_found" = x"no"; then
106                 echo "***"
107                 echo "*** xfconf-query was not found on your system."
108                 echo "*** The wallpaper won't work without it installed."
109                 echo "***"
110         fi
111 fi
112 ])