Git Repositories

2006-07-27 Benedikt Meurer <benny@xfce.org>
[thunar.git] / acinclude.m4
1 dnl $Id$
2 dnl
3 dnl Copyright (c) 2004-2006
4 dnl         The Thunar development team. All rights reserved.
5 dnl
6 dnl Written for Thunar by Benedikt Meurer <benny@xfce.org>.
7 dnl
8
9
10
11 dnl # BM_THUNAR_PLUGIN_APR()
12 dnl #
13 dnl # Check whether the "Advanced Properties" plugin
14 dnl # should be built and installed.
15 dnl #
16 AC_DEFUN([BM_THUNAR_PLUGIN_APR],
17 [
18 AC_ARG_ENABLE([apr-plugin], [AC_HELP_STRING([--disable-apr-plugin], [Don't build the thunar-apr plugin, see plugins/thunar-apr/README])],
19   [ac_bm_thunar_plugin_apr=$enable_val], [ac_bm_thunar_plugin_apr=yes])
20 AC_MSG_CHECKING([whether to build the thunar-apr plugin])
21 AM_CONDITIONAL([THUNAR_PLUGIN_APR], [test x"$ac_bm_thunar_plugin_apr" = x"yes"])
22 AC_MSG_RESULT([$ac_bm_thunar_plugin_apr])
23
24 dnl Check for libexif (for the "Image" properties page)
25 XDT_CHECK_OPTIONAL_PACKAGE([EXIF], [libexif], [0.6.0], [exif], [Exif support])
26 ])
27
28
29
30 dnl # BM_THUNAR_PLUGIN_SBR()
31 dnl #
32 dnl # Check whether the "Simple Builtin Renamers" plugin
33 dnl # should be built and installed.
34 dnl #
35 AC_DEFUN([BM_THUNAR_PLUGIN_SBR],
36 [
37 AC_ARG_ENABLE([sbr-plugin], AC_HELP_STRING([--disable-sbr-plugin], [Don't build the thunar-sbr plugin, see plugins/thunar-sbr/README]),
38   [ac_bm_thunar_plugin_sbr=$enable_val], [ac_bm_thunar_plugin_sbr=yes])
39 AC_MSG_CHECKING([whether to build the thunar-sbr plugin])
40 AM_CONDITIONAL([THUNAR_PLUGIN_SBR], [test x"$ac_bm_thunar_plugin_sbr" = x"yes"])
41 AC_MSG_RESULT([$ac_bm_thunar_plugin_sbr])
42
43 dnl Check for PCRE (for the "Search & Replace" renamer)
44 XDT_CHECK_OPTIONAL_PACKAGE([PCRE], [libpcre], [6.0], [pcre], [Regular expression support])
45 ])
46
47
48
49 dnl # BM_THUNAR_PLUGIN_TPA()
50 dnl #
51 dnl # Check whether the "Trash Panel Applet" plugin should
52 dnl # be built and installed (this is actually a plugin
53 dnl # for the Xfce panel, not for Thunar).
54 dnl #
55 AC_DEFUN([BM_THUNAR_PLUGIN_TPA],
56 [
57 AC_ARG_ENABLE([tpa-plugin], AC_HELP_STRING([--disable-tpa-plugin], [Don't build the thunar-tpa plugin, see plugins/thunar-tpa/README]),
58   [ac_bm_thunar_plugin_tpa=$enable_val], [ac_bm_thunar_plugin_tpa=yes])
59 if test x"$ac_bm_thunar_plugin_tpa" = x"yes"; then
60   XDT_CHECK_PACKAGE([LIBXFCE4PANEL], [libxfce4panel-1.0], [4.3.90],
61   [
62     dnl # Can only build thunar-tpa if D-BUS was found previously
63     ac_bm_thunar_plugin_tpa=$DBUS_FOUND
64   ],
65   [
66     dnl # Cannot build thunar-tpa if xfce4-panel is not installed
67     ac_bm_thunar_plugin_tpa=no
68   ])
69 fi
70 AC_MSG_CHECKING([whether to build the thunar-tpa plugin])
71 AM_CONDITIONAL([THUNAR_PLUGIN_TPA], [test x"$ac_bm_thunar_plugin_tpa" = x"yes"])
72 AC_MSG_RESULT([$ac_bm_thunar_plugin_tpa])
73 ])
74
75
76
77 dnl # BM_THUNAR_PLUGIN_UCA()
78 dnl #
79 dnl # Check whether the "User Customizable Actions" plugin
80 dnl # should be built and installed.
81 dnl #
82 AC_DEFUN([BM_THUNAR_PLUGIN_UCA],
83 [
84 AC_ARG_ENABLE([uca-plugin], AC_HELP_STRING([--disable-uca-plugin], [Don't build the thunar-uca plugin, see plugins/thunar-uca/README]),
85   [ac_bm_thunar_plugin_uca=$enable_val], [ac_bm_thunar_plugin_uca=yes])
86 AC_MSG_CHECKING([whether to build the thunar-uca plugin])
87 AM_CONDITIONAL([THUNAR_PLUGIN_UCA], [test x"$ac_bm_thunar_plugin_uca" = x"yes"])
88 AC_MSG_RESULT([$ac_bm_thunar_plugin_uca])
89 ])
90
91
92
93 dnl # BM_THUNAR_VFS_MONITOR_IMPL()
94 dnl #
95 dnl # Determine the file system monitoring to use for
96 dnl # thunar-vfs.
97 dnl #
98 dnl # Sets LIBFAM_CFLAGS and LIBFAM_LIBS and defines
99 dnl # HAVE_FAM_H and HAVE_LIBFAM if FAM/Gamin were
100 dnl # found.
101 dnl #
102 dnl # Sets $ac_bm_thunar_vfs_monitor_impl to "FAM",
103 dnl # "Gamin" or "none".
104 dnl #
105 AC_DEFUN([BM_THUNAR_VFS_MONITOR_IMPL],
106 [
107 LIBFAM_CFLAGS=""
108 LIBFAM_LIBS=""
109 have_libfam=no
110 ac_bm_thunar_vfs_monitor_impl="none"
111 XDT_CHECK_PACKAGE([LIBFAM], [gamin], [0.1.0],
112 [
113   have_libfam=yes
114   ac_bm_thunar_vfs_monitor_impl="Gamin"
115 ],
116 [
117   dnl Fallback to a generic FAM check
118   AC_CHECK_HEADERS([fam.h],
119   [
120     AC_CHECK_LIB([fam], [FAMOpen],
121     [
122       have_libfam="yes" LIBFAM_LIBS="-lfam"
123       ac_bm_thunar_vfs_monitor_impl="FAM"
124     ])
125   ])
126 ])
127 if test x"$have_libfam" = x"yes"; then
128   dnl Define appropriate symbols
129   AC_DEFINE([HAVE_FAM_H], [1], [Define to 1 if you have the <fam.h> header file.])
130   AC_DEFINE([HAVE_LIBFAM], [1], [Define to 1 if the File Alteration Monitor is available.])
131
132   dnl Check for FAMNoExists (currently Gamin only)
133   save_LIBS="$LIBS"
134   LIBS="$LIBS $LIBFAM_LIBS"
135   AC_CHECK_FUNCS([FAMNoExists])
136   LIBS="$save_LIBS"
137 fi
138 AC_SUBST([LIBFAM_CFLAGS])
139 AC_SUBST([LIBFAM_LIBS])
140 ])
141
142
143
144 dnl # BM_THUNAR_VFS_OS_IMPL()
145 dnl #
146 dnl # Determine the operating system support to use
147 dnl # for thunar-vfs.
148 dnl #
149 dnl # Sets ac_bm_thunar_vfs_os_impl to "bsd" or "generic" and
150 dnl # defines the automake conditional THUNAR_VFS_OS_IMPL_BSD.
151 dnl #
152 AC_DEFUN([BM_THUNAR_VFS_OS_IMPL],
153 [
154   dnl # Auto-detect target operating system support
155   AC_MSG_CHECKING([for operating system support])
156   case "$target_os" in
157   dragonfly*|freebsd*|netbsd*|openbsd*|darwin*)
158     dnl # The BSD Family is fully supported
159     ac_bm_thunar_vfs_os_impl=bsd
160     ;;
161
162   *)
163     dnl # Otherwise fallback to generic OS support
164     ac_bm_thunar_vfs_os_impl=generic
165   esac
166   AC_MSG_RESULT([$ac_bm_thunar_vfs_os_impl])
167
168   dnl # Set automake conditionals appropriately
169   AM_CONDITIONAL([THUNAR_VFS_OS_IMPL_BSD], [test x"$ac_bm_thunar_vfs_os_impl" = x"bsd"])
170 ])
171
172
173
174 dnl # BM_THUNAR_VFS_VOLUME_IMPL()
175 dnl #
176 dnl # Determines the volume manager implementation to
177 dnl # use for thunar-vfs.
178 dnl #
179 dnl # Sets ac_bm_thunar_vfs_volume_impl to "freebsd",
180 dnl # "hal" or "none".
181 dnl #
182 AC_DEFUN([BM_THUNAR_VFS_VOLUME_IMPL],
183 [
184   dnl The --with-volume-manager option
185   AC_ARG_WITH([volume-manager],
186 AC_HELP_STRING([--with-volume-manager=@<:@auto/freebsd/hal/none@:>@], [The volume manager implementation @<:@default=auto@:>@]),
187     [], [with_volume_manager=auto])
188
189   dnl # Check if we should try to auto-detect
190   if test x"$with_volume_manager" = x"freebsd"; then
191     ac_bm_thunar_vfs_volume_impl=freebsd
192   elif test x"$with_volume_manager" = x"hal"; then
193     ac_bm_thunar_vfs_volume_impl=hal
194   elif test x"$with_volume_manager" = x"none"; then
195     ac_bm_thunar_vfs_volume_impl=none
196   else
197     dnl # Check target platform (auto-detection)
198     case "$target_os" in
199     freebsd*)
200       dnl # FreeBSD is fully supported
201       ac_bm_thunar_vfs_volume_impl=freebsd
202       ;;
203     *)
204       dnl # Otherwise, check if we have HAL
205       XDT_CHECK_PACKAGE([HAL], [hal-storage], [0.5.0], [ac_bm_thunar_vfs_volume_impl=hal], [ac_bm_thunar_vfs_volume_impl=none])
206       ;;
207     esac
208   fi
209
210   dnl # We need HAL >= 0.5.x and D-BUS >= 0.23 for the HAL volume manager
211   if test x"$ac_bm_thunar_vfs_volume_impl" = x"hal"; then
212     XDT_CHECK_PACKAGE([HAL], [hal-storage], [0.5.0])
213     XDT_CHECK_PACKAGE([HAL_DBUS], [dbus-glib-1], [0.23])
214   fi
215
216   dnl # Set config.h variables depending on what we're going to use
217   AC_MSG_CHECKING([for the volume manager implemenation])
218   case "$ac_bm_thunar_vfs_volume_impl" in
219   freebsd)
220     AC_DEFINE([THUNAR_VFS_VOLUME_IMPL_FREEBSD], [1], [Define to 1 if the FreeBSD volume manager implementation should be used])
221     ;;
222
223   hal)
224     AC_DEFINE([THUNAR_VFS_VOLUME_IMPL_HAL], [1], [Define to 1 if the HAL volume manager implementation should be used])
225     ;;
226
227   *)
228     AC_DEFINE([THUNAR_VFS_VOLUME_IMPL_NONE], [1], [Define to 1 if no volume manager implementation should be used])
229     ;;
230   esac
231   AC_MSG_RESULT([$ac_bm_thunar_vfs_volume_impl])
232
233   dnl # Set automake conditionals appropriately
234   AM_CONDITIONAL([THUNAR_VFS_VOLUME_IMPL_FREEBSD], [test x"$ac_bm_thunar_vfs_volume_impl" = x"freebsd"])
235   AM_CONDITIONAL([THUNAR_VFS_VOLUME_IMPL_HAL], [test x"$ac_bm_thunar_vfs_volume_impl" = x"hal"])
236   AM_CONDITIONAL([THUNAR_VFS_VOLUME_IMPL_NONE], [test x"$ac_bm_thunar_vfs_volume_impl" = x"none"])
237 ])