Git Repositories

2006-02-13 Benedikt Meurer <benny@xfce.org>
[thunar.git] / acinclude.m4
1 dnl $Id$
2 dnl
3 dnl Copyright (c) 2004-2006
4 dnl         The Thunar development team. All rights reserved.
5 dnl
6 dnl Written for Thunar by Benedikt Meurer <benny@xfce.org>.
7 dnl
8
9
10
11 dnl # BM_THUNAR_VFS_VOLUME_IMPL()
12 dnl #
13 dnl # Determines the volume manager implementation to
14 dnl # use for thunar-vfs.
15 dnl #
16 AC_DEFUN([BM_THUNAR_VFS_VOLUME_IMPL],
17 [
18   dnl The --with-volume-manager option
19   AC_ARG_WITH([volume-manager],
20 AC_HELP_STRING([--with-volume-manager=@<:@auto/freebsd/hal/none@:>@], [The volume manager implementation @<:@default=auto@:>@]),
21     [], [with_volume_manager=auto])
22
23   dnl # Check if we should try to auto-detect
24   if test x"$with_volume_manager" = x"auto"; then
25     dnl # Check target platform
26     case "$target_os" in
27     freebsd*)
28       dnl # FreeBSD is fully supported
29       with_volume_manager=freebsd
30       ;;
31     *)
32       dnl # Otherwise, check if we have HAL
33       XDT_CHECK_PACKAGE([HAL], [hal-storage], [0.5.0], [with_volume_manager=hal], [with_volume_manager=none])
34       ;;
35     esac
36   fi
37
38   dnl # We need HAL >= 0.5.x and D-BUS >= 0.23 for the HAL volume manager
39   if test x"$with_volume_manager" = x"hal"; then
40     XDT_CHECK_PACKAGE([HAL], [hal-storage], [0.5.0])
41     XDT_CHECK_PACKAGE([HAL_DBUS], [dbus-glib-1], [0.23])
42   fi
43
44   dnl # Set config.h variables depending on what we're going to use
45   AC_MSG_CHECKING([for the volume manager implemenation])
46   case "$with_volume_manager" in
47   freebsd)
48     AC_DEFINE([THUNAR_VFS_VOLUME_IMPL_FREEBSD], [1], [Define to 1 if the FreeBSD volume manager implementation should be used])
49     ;;
50
51   hal)
52     AC_DEFINE([THUNAR_VFS_VOLUME_IMPL_HAL], [1], [Define to 1 if the HAL volume manager implementation should be used])
53     ;;
54
55   *)
56     AC_DEFINE([THUNAR_VFS_VOLUME_IMPL_NONE], [1], [Define to 1 if no volume manager implementation should be used])
57     with_volume_manager=none
58     ;;
59   esac
60   AC_MSG_RESULT([$with_volume_manager])
61
62   dnl # Set automake conditionals appropriately
63   AM_CONDITIONAL([THUNAR_VFS_VOLUME_IMPL_FREEBSD], [test x"$with_volume_manager" = x"freebsd"])
64   AM_CONDITIONAL([THUNAR_VFS_VOLUME_IMPL_HAL], [test x"$with_volume_manager" = x"hal"])
65   AM_CONDITIONAL([THUNAR_VFS_VOLUME_IMPL_NONE], [test x"$with_volume_manager" = x"none"])
66 ])