Git Repositories

2007-01-07 Benedikt Meurer <benny@xfce.org>
[thunar.git] / acinclude.m4
1 dnl $Id$
2 dnl
3 dnl Copyright (c) 2004-2006
4 dnl         The Thunar development team. All rights reserved.
5 dnl
6 dnl Written for Thunar by Benedikt Meurer <benny@xfce.org>.
7 dnl
8
9
10
11 dnl # BM_THUNAR_PLUGIN_APR()
12 dnl #
13 dnl # Check whether the "Advanced Properties" plugin
14 dnl # should be built and installed.
15 dnl #
16 AC_DEFUN([BM_THUNAR_PLUGIN_APR],
17 [
18 AC_ARG_ENABLE([apr-plugin], [AC_HELP_STRING([--disable-apr-plugin], [Don't build the thunar-apr plugin, see plugins/thunar-apr/README])],
19   [ac_bm_thunar_plugin_apr=$enable_val], [ac_bm_thunar_plugin_apr=yes])
20 AC_MSG_CHECKING([whether to build the thunar-apr plugin])
21 AM_CONDITIONAL([THUNAR_PLUGIN_APR], [test x"$ac_bm_thunar_plugin_apr" = x"yes"])
22 AC_MSG_RESULT([$ac_bm_thunar_plugin_apr])
23
24 dnl Check for libexif (for the "Image" properties page)
25 XDT_CHECK_OPTIONAL_PACKAGE([EXIF], [libexif], [0.6.0], [exif], [Exif support])
26 ])
27
28
29
30 dnl # BM_THUNAR_PLUGIN_SBR()
31 dnl #
32 dnl # Check whether the "Simple Builtin Renamers" plugin
33 dnl # should be built and installed.
34 dnl #
35 AC_DEFUN([BM_THUNAR_PLUGIN_SBR],
36 [
37 AC_ARG_ENABLE([sbr-plugin], AC_HELP_STRING([--disable-sbr-plugin], [Don't build the thunar-sbr plugin, see plugins/thunar-sbr/README]),
38   [ac_bm_thunar_plugin_sbr=$enable_val], [ac_bm_thunar_plugin_sbr=yes])
39 AC_MSG_CHECKING([whether to build the thunar-sbr plugin])
40 AM_CONDITIONAL([THUNAR_PLUGIN_SBR], [test x"$ac_bm_thunar_plugin_sbr" = x"yes"])
41 AC_MSG_RESULT([$ac_bm_thunar_plugin_sbr])
42
43 dnl Check for PCRE (for the "Search & Replace" renamer)
44 XDT_CHECK_OPTIONAL_PACKAGE([PCRE], [libpcre], [6.0], [pcre], [Regular expression support])
45 ])
46
47
48
49 dnl # BM_THUNAR_PLUGIN_TPA()
50 dnl #
51 dnl # Check whether the "Trash Panel Applet" plugin should
52 dnl # be built and installed (this is actually a plugin
53 dnl # for the Xfce panel, not for Thunar).
54 dnl #
55 AC_DEFUN([BM_THUNAR_PLUGIN_TPA],
56 [
57 AC_ARG_ENABLE([tpa-plugin], AC_HELP_STRING([--disable-tpa-plugin], [Don't build the thunar-tpa plugin, see plugins/thunar-tpa/README]),
58   [ac_bm_thunar_plugin_tpa=$enable_val], [ac_bm_thunar_plugin_tpa=yes])
59 if test x"$ac_bm_thunar_plugin_tpa" = x"yes"; then
60   XDT_CHECK_PACKAGE([LIBXFCE4PANEL], [libxfce4panel-1.0], [4.3.90],
61   [
62     dnl # Can only build thunar-tpa if D-BUS was found previously
63     ac_bm_thunar_plugin_tpa=$DBUS_FOUND
64   ],
65   [
66     dnl # Cannot build thunar-tpa if xfce4-panel is not installed
67     ac_bm_thunar_plugin_tpa=no
68   ])
69 else
70   ac_bm_thunar_plugin_tpa=no
71 fi
72 AC_MSG_CHECKING([whether to build the thunar-tpa plugin])
73 AM_CONDITIONAL([THUNAR_PLUGIN_TPA], [test x"$ac_bm_thunar_plugin_tpa" = x"yes"])
74 AC_MSG_RESULT([$ac_bm_thunar_plugin_tpa])
75 ])
76
77
78
79 dnl # BM_THUNAR_PLUGIN_UCA()
80 dnl #
81 dnl # Check whether the "User Customizable Actions" plugin
82 dnl # should be built and installed.
83 dnl #
84 AC_DEFUN([BM_THUNAR_PLUGIN_UCA],
85 [
86 AC_ARG_ENABLE([uca-plugin], AC_HELP_STRING([--disable-uca-plugin], [Don't build the thunar-uca plugin, see plugins/thunar-uca/README]),
87   [ac_bm_thunar_plugin_uca=$enable_val], [ac_bm_thunar_plugin_uca=yes])
88 AC_MSG_CHECKING([whether to build the thunar-uca plugin])
89 AM_CONDITIONAL([THUNAR_PLUGIN_UCA], [test x"$ac_bm_thunar_plugin_uca" = x"yes"])
90 AC_MSG_RESULT([$ac_bm_thunar_plugin_uca])
91 ])
92
93
94
95 dnl # BM_THUNAR_VFS_MONITOR_IMPL()
96 dnl #
97 dnl # Determine the file system monitoring to use for
98 dnl # thunar-vfs.
99 dnl #
100 dnl # Sets LIBFAM_CFLAGS and LIBFAM_LIBS and defines
101 dnl # HAVE_FAM_H and HAVE_LIBFAM if FAM/Gamin were
102 dnl # found.
103 dnl #
104 dnl # Sets $ac_bm_thunar_vfs_monitor_impl to "FAM",
105 dnl # "Gamin" or "none".
106 dnl #
107 AC_DEFUN([BM_THUNAR_VFS_MONITOR_IMPL],
108 [
109 LIBFAM_CFLAGS=""
110 LIBFAM_LIBS=""
111 have_libfam=no
112 ac_bm_thunar_vfs_monitor_impl="none"
113 XDT_CHECK_PACKAGE([LIBFAM], [gamin], [0.1.0],
114 [
115   have_libfam=yes
116   ac_bm_thunar_vfs_monitor_impl="Gamin"
117 ],
118 [
119   dnl Fallback to a generic FAM check
120   AC_CHECK_HEADERS([fam.h],
121   [
122     AC_CHECK_LIB([fam], [FAMOpen],
123     [
124       have_libfam="yes" LIBFAM_LIBS="-lfam"
125       ac_bm_thunar_vfs_monitor_impl="FAM"
126     ])
127   ])
128 ])
129 if test x"$have_libfam" = x"yes"; then
130   dnl Define appropriate symbols
131   AC_DEFINE([HAVE_FAM_H], [1], [Define to 1 if you have the <fam.h> header file.])
132   AC_DEFINE([HAVE_LIBFAM], [1], [Define to 1 if the File Alteration Monitor is available.])
133
134   dnl Check for FAMNoExists (currently Gamin only)
135   save_LIBS="$LIBS"
136   LIBS="$LIBS $LIBFAM_LIBS"
137   AC_CHECK_FUNCS([FAMNoExists])
138   LIBS="$save_LIBS"
139 fi
140 AC_SUBST([LIBFAM_CFLAGS])
141 AC_SUBST([LIBFAM_LIBS])
142 ])
143
144
145
146 dnl # BM_THUNAR_VFS_OS_IMPL()
147 dnl #
148 dnl # Determine the operating system support to use
149 dnl # for thunar-vfs.
150 dnl #
151 dnl # Sets ac_bm_thunar_vfs_os_impl to "bsd" or "generic" and
152 dnl # defines the automake conditional THUNAR_VFS_OS_IMPL_BSD.
153 dnl #
154 AC_DEFUN([BM_THUNAR_VFS_OS_IMPL],
155 [
156   dnl # Auto-detect target operating system support
157   AC_MSG_CHECKING([for operating system support])
158   case "$target_os" in
159   dragonfly*|freebsd*|netbsd*|openbsd*|darwin*)
160     dnl # The BSD Family is fully supported
161     ac_bm_thunar_vfs_os_impl=bsd
162     ;;
163
164   *)
165     dnl # Otherwise fallback to generic OS support
166     ac_bm_thunar_vfs_os_impl=generic
167   esac
168   AC_MSG_RESULT([$ac_bm_thunar_vfs_os_impl])
169
170   dnl # Set automake conditionals appropriately
171   AM_CONDITIONAL([THUNAR_VFS_OS_IMPL_BSD], [test x"$ac_bm_thunar_vfs_os_impl" = x"bsd"])
172 ])
173
174
175
176 dnl # BM_THUNAR_VFS_VOLUME_IMPL()
177 dnl #
178 dnl # Determines the volume manager implementation to
179 dnl # use for thunar-vfs.
180 dnl #
181 dnl # Sets ac_bm_thunar_vfs_volume_impl to "freebsd",
182 dnl # "hal" or "none".
183 dnl #
184 AC_DEFUN([BM_THUNAR_VFS_VOLUME_IMPL],
185 [
186   dnl The --with-volume-manager option
187   AC_ARG_WITH([volume-manager],
188 AC_HELP_STRING([--with-volume-manager=@<:@auto/freebsd/hal/none@:>@], [The volume manager implementation @<:@default=auto@:>@]),
189     [], [with_volume_manager=auto])
190
191   dnl # Check if we should try to auto-detect
192   if test x"$with_volume_manager" = x"freebsd"; then
193     ac_bm_thunar_vfs_volume_impl=freebsd
194   elif test x"$with_volume_manager" = x"hal"; then
195     ac_bm_thunar_vfs_volume_impl=hal
196   elif test x"$with_volume_manager" = x"none"; then
197     ac_bm_thunar_vfs_volume_impl=none
198   else
199     dnl # Check if HAL is available
200     XDT_CHECK_PACKAGE([HAL], [hal-storage], [0.5.0],
201     [
202       dnl # HAL is available, use it
203       ac_bm_thunar_vfs_volume_impl=hal
204     ],
205     [
206       dnl # Check operating system type
207       case "$target_os" in
208       freebsd*)
209         dnl # FreeBSD is fully supported
210         ac_bm_thunar_vfs_volume_impl=freebsd
211         ;;
212       *)
213         dnl # Otherwise no volume support
214         ac_bm_thunar_vfs_volume_impl=none
215         ;;
216       esac
217     ])
218   fi
219
220   dnl # We need HAL >= 0.5.x and D-BUS >= 0.23 for the HAL volume manager
221   if test x"$ac_bm_thunar_vfs_volume_impl" = x"hal"; then
222     XDT_CHECK_PACKAGE([EXO_HAL], [exo-hal-0.3], [0.3.1.13])
223     XDT_CHECK_PACKAGE([HAL], [hal-storage], [0.5.0])
224     XDT_CHECK_PACKAGE([HAL_DBUS], [dbus-glib-1], [0.23])
225   fi
226
227   dnl # Set config.h variables depending on what we're going to use
228   AC_MSG_CHECKING([for the volume manager implemenation])
229   case "$ac_bm_thunar_vfs_volume_impl" in
230   freebsd)
231     AC_DEFINE([THUNAR_VFS_VOLUME_IMPL_FREEBSD], [1], [Define to 1 if the FreeBSD volume manager implementation should be used])
232     ;;
233
234   hal)
235     AC_DEFINE([THUNAR_VFS_VOLUME_IMPL_HAL], [1], [Define to 1 if the HAL volume manager implementation should be used])
236     ;;
237
238   *)
239     AC_DEFINE([THUNAR_VFS_VOLUME_IMPL_NONE], [1], [Define to 1 if no volume manager implementation should be used])
240     ;;
241   esac
242   AC_MSG_RESULT([$ac_bm_thunar_vfs_volume_impl])
243
244   dnl # Set automake conditionals appropriately
245   AM_CONDITIONAL([THUNAR_VFS_VOLUME_IMPL_FREEBSD], [test x"$ac_bm_thunar_vfs_volume_impl" = x"freebsd"])
246   AM_CONDITIONAL([THUNAR_VFS_VOLUME_IMPL_HAL], [test x"$ac_bm_thunar_vfs_volume_impl" = x"hal"])
247   AM_CONDITIONAL([THUNAR_VFS_VOLUME_IMPL_NONE], [test x"$ac_bm_thunar_vfs_volume_impl" = x"none"])
248 ])