Git Repositories

I18n: Update translation lt (100%).
[thunar.git] / configure.ac.in
1 # vi:set et ai sw=2 sts=2 ts=2: */
2 #-
3 # Copyright (c) 2004-2007 Benedikt Meurer <benny@xfce.org>
4 # Copyright (c) 2009-2011 Jannis Pohlmann <jannis@xfce.org>
5 # Copyright (c) 2004-2015 Xfce Development Team <xfce4-dev@xfce.org>
6 #
7 # This program is free software; you can redistribute it and/or 
8 # modify it under the terms of the GNU General Public License as
9 # published by the Free Software Foundation; either version 2 of 
10 # the License, or (at your option) any later version.
11 #
12 # This program is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the 
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public 
18 # License along with this program; if not, write to the Free 
19 # Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
20 # Boston, MA 02110-1301, USA.
21
22 dnl ***************************
23 dnl *** Version information ***
24 dnl ***************************
25 m4_define([thunarx_verinfo], [0:0:0])
26 m4_define([thunarx_version_api], [2])
27 m4_define([thunar_version_major], [1])
28 m4_define([thunar_version_minor], [6])
29 m4_define([thunar_version_micro], [10])
30 m4_define([thunar_version_nano], [])
31 m4_define([thunar_version_build], [@REVISION@])
32 m4_define([thunar_version_tag], [git])
33 m4_define([thunar_version], [thunar_version_major().thunar_version_minor().thunar_version_micro()ifelse(thunar_version_nano(), [], [], [.thunar_version_nano()])ifelse(thunar_version_tag(), [git], [thunar_version_tag()-thunar_version_build()], [thunar_version_tag()])])
34
35 dnl *******************************************
36 dnl *** Debugging support for GIT snapshots ***
37 dnl *******************************************
38 m4_define([thunar_debug_default], [ifelse(thunar_version_tag(), [git], [yes], [minimum])])
39
40 dnl ***************************
41 dnl *** Initialize autoconf ***
42 dnl ***************************
43 AC_COPYRIGHT([Copyright (c) 2004-2015 The Thunar development team. All rights reserved.])
44 AC_INIT([Thunar], [thunar_version], [http://bugzilla.xfce.org/], [Thunar])
45 AC_PREREQ([2.60])
46 AC_CONFIG_MACRO_DIR([m4])
47 AC_CANONICAL_TARGET()
48 AC_REVISION([thunar_version_build])
49
50 dnl ***************************
51 dnl *** Initialize automake ***
52 dnl ***************************
53 AM_INIT_AUTOMAKE([1.11 dist-bzip2 tar-ustar no-dist-gzip])
54 AC_CONFIG_HEADERS([config.h])
55 AM_MAINTAINER_MODE()
56 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
57
58 dnl *******************************
59 dnl *** Check for UNIX variants ***
60 dnl *******************************
61 AC_AIX()
62 AC_ISC_POSIX()
63 AC_MINIX()
64
65 if test "x$target_os" = "xlinux-gnu"; then
66   AC_DEFINE([HAVE_LINUX], [], [Whether we are building on Linux or not])
67 fi
68
69 dnl ********************************
70 dnl *** Check for basic programs ***
71 dnl ********************************
72 AC_PROG_CC()
73 AC_PROG_LD()
74 AM_PROG_CC_C_O()
75 AC_PROG_INSTALL()
76 IT_PROG_INTLTOOL()
77 AC_CHECK_PROGS([PERL], [perl5 perl])
78 m4_ifdef([AC_PROG_SED], [AC_PROG_SED], [AC_CHECK_PROG(SED, sed, sed)])
79
80 dnl **************************
81 dnl *** Initialize libtool ***
82 dnl **************************
83 LT_PREREQ([2.4])
84 LT_INIT([disable-static])
85
86 dnl **************************************
87 dnl *** Substitute version information ***
88 dnl **************************************
89 THUNARX_VERINFO=thunarx_verinfo()
90 THUNARX_VERSION_API=thunarx_version_api()
91 THUNAR_VERSION_MAJOR=thunar_version_major()
92 THUNAR_VERSION_MINOR=thunar_version_minor()
93 THUNAR_VERSION_MICRO=thunar_version_micro()
94 AC_SUBST([THUNARX_VERINFO])
95 AC_SUBST([THUNARX_VERSION_API])
96 AC_SUBST([THUNAR_VERSION_MAJOR])
97 AC_SUBST([THUNAR_VERSION_MINOR])
98 AC_SUBST([THUNAR_VERSION_MICRO])
99
100 dnl ******************************
101 dnl *** Set helper path prefix ***
102 dnl ******************************
103 AC_ARG_WITH([helper-path-prefix],
104             [AC_HELP_STRING([--with-helper-path-prefix=PATH],
105                             [Path prefix under which helper executables will be installed (default: $libdir)])],
106             [HELPER_PATH_PREFIX="$withval"],
107             [HELPER_PATH_PREFIX="$libdir"])
108 AC_SUBST([HELPER_PATH_PREFIX])
109
110 dnl ***********************************************
111 dnl *** Work-around system-specific limitations ***
112 dnl ***********************************************
113 AC_SYS_LARGEFILE()
114
115 dnl **********************************
116 dnl *** Check for standard headers ***
117 dnl **********************************
118 AC_CHECK_HEADERS([ctype.h errno.h fcntl.h grp.h limits.h locale.h memory.h \
119                   paths.h pwd.h sched.h signal.h stdarg.h stdlib.h string.h \
120                   sys/mman.h sys/param.h sys/stat.h sys/time.h sys/types.h \
121                   sys/uio.h sys/wait.h time.h])
122
123 dnl ************************************
124 dnl *** Check for standard functions ***
125 dnl ************************************
126 AC_FUNC_MMAP()
127 AC_CHECK_FUNCS([localeconv mkdtemp pread pwrite sched_yield setgroupent \
128                 setpassent strcoll strlcpy strptime symlink atexit])
129
130 dnl ******************************
131 dnl *** Check for i18n support ***
132 dnl ******************************
133 XDT_I18N([@LINGUAS@])
134
135 dnl *********************
136 dnl *** Check for X11 ***
137 dnl *********************
138 XDT_CHECK_LIBX11_REQUIRE()
139
140 dnl ***********************************
141 dnl *** Check for required packages ***
142 dnl ***********************************
143 XDT_CHECK_PACKAGE([EXO], [exo-1], [0.10.0])
144 XDT_CHECK_PACKAGE([GLIB], [glib-2.0], [2.30.0])
145 XDT_CHECK_PACKAGE([GIO], [gio-2.0], [2.30.0])
146 XDT_CHECK_PACKAGE([GTHREAD], [gthread-2.0], [2.30.0])
147 XDT_CHECK_PACKAGE([GMODULE], [gmodule-2.0], [2.30.0])
148 XDT_CHECK_PACKAGE([GTK], [gtk+-2.0], [2.24.0])
149 XDT_CHECK_PACKAGE([GDK_PIXBUF], [gdk-pixbuf-2.0], [2.14.0])
150 XDT_CHECK_PACKAGE([LIBXFCE4UTIL], [libxfce4util-1.0], [4.10.0])
151 XDT_CHECK_PACKAGE([LIBXFCE4UI], [libxfce4ui-1], [4.10.0])
152 XDT_CHECK_PACKAGE([XFCONF], [libxfconf-0], [4.10.0])
153
154 dnl ********************************************
155 dnl *** Check for session management support ***
156 dnl ********************************************
157 XDT_CHECK_LIBSM()
158
159 dnl **********************************
160 dnl *** Optional GIO UNIX features ***
161 dnl **********************************
162 XDT_CHECK_OPTIONAL_PACKAGE([GIO_UNIX], [gio-unix-2.0],
163                            [2.30.0], [gio-unix], [GIO UNIX features])
164
165 dnl **********************************
166 dnl *** Optional support for D-BUS ***
167 dnl **********************************
168 XDT_CHECK_OPTIONAL_PACKAGE([DBUS], [dbus-glib-1],
169                            [0.34], [dbus], [D-BUS support])
170
171 dnl ***************************************************************
172 dnl *** Optional support for GUDev (required for thunar-volman) ***
173 dnl ***************************************************************
174 XDT_CHECK_OPTIONAL_PACKAGE([GUDEV], [gudev-1.0], [145], [gudev], 
175                            [GUDev (required for thunar-volman)])
176
177 dnl **************************************
178 dnl *** Optional support for libnotify ***
179 dnl **************************************
180 XDT_CHECK_OPTIONAL_PACKAGE([LIBNOTIFY], [libnotify], [0.4.0], [notifications],
181                            [Mount notification support], [yes])
182
183 dnl ***********************************
184 dnl *** Check for debugging support ***
185 dnl ***********************************
186 XDT_FEATURE_DEBUG([thunar_debug_default])
187
188 dnl **************************************
189 dnl *** Check for linker optimizations ***
190 dnl **************************************
191 XDT_FEATURE_LINKER_OPTS()
192
193 dnl dnl ****************************************
194 dnl dnl *** Check for ELF visibility support ***
195 dnl dnl ****************************************
196 dnl XDT_FEATURE_VISIBILITY()
197
198 dnl *********************************
199 dnl *** Substitute platform flags ***
200 dnl *********************************
201 AC_MSG_CHECKING([PLATFORM_CPPFLAGS])
202 AC_MSG_RESULT([$PLATFORM_CPPFLAGS])
203 AC_SUBST([PLATFORM_CPPFLAGS])
204 AC_MSG_CHECKING([PLATFORM_CFLAGS])
205 AC_MSG_RESULT([$PLATFORM_CFLAGS])
206 AC_SUBST([PLATFORM_CFLAGS])
207 AC_MSG_CHECKING([PLATFORM_LDFLAGS])
208 AC_MSG_RESULT([$PLATFORM_LDFLAGS])
209 AC_SUBST([PLATFORM_LDFLAGS])
210
211 dnl ************************************
212 dnl *** Check for additional plugins ***
213 dnl ************************************
214 BM_THUNAR_PLUGIN_APR()
215 BM_THUNAR_PLUGIN_SBR()
216 BM_THUNAR_PLUGIN_TPA()
217 BM_THUNAR_PLUGIN_UCA()
218 BM_THUNAR_PLUGIN_WALLPAPER()
219
220 AC_OUTPUT([
221 Makefile
222 docs/Makefile
223 docs/design/Makefile
224 docs/papers/Makefile
225 examples/Makefile
226 examples/tex-open-terminal/Makefile
227 icons/Makefile
228 icons/16x16/Makefile
229 icons/24x24/Makefile
230 icons/48x48/Makefile
231 icons/64x64/Makefile
232 icons/128x128/Makefile
233 icons/scalable/Makefile
234 pixmaps/Makefile
235 plugins/Makefile
236 plugins/thunar-apr/Makefile
237 plugins/thunar-sbr/Makefile
238 plugins/thunar-sendto-email/Makefile
239 plugins/thunar-tpa/Makefile
240 plugins/thunar-uca/Makefile
241 plugins/thunar-wallpaper/Makefile
242 po/Makefile.in
243 thunar/Makefile
244 thunarx/Makefile
245 thunarx/thunarx-2.pc
246 thunarx/thunarx-config.h
247 ])
248
249 dnl ***************************
250 dnl *** Print configuration ***
251 dnl ***************************
252 echo
253 echo "Build Configuration:"
254 echo
255 if test x"$DBUS_FOUND" = x"yes"; then
256 echo "* D-BUS support:                      yes"
257 else
258 echo "* D-BUS support:                      no"
259 fi
260 if test x"$GIO_UNIX_FOUND" = x"yes"; then
261 echo "* GIO UNIX features:                  yes"
262 else
263 echo "* GIO UNIX features:                  no"
264 fi
265 if test x"$GUDEV_FOUND" = x"yes"; then
266 echo "* GUDev (required for thunar-volman): yes"
267 else
268 echo "* GUDev (required for thunar-volman): no"
269 fi
270 if test x"$LIBNOTIFY_FOUND" = x"yes"; then
271 echo "* Mount notification support:         yes"
272 else
273 echo "* Mount notification support:         no"
274 fi
275 echo "* Debug Support:                      $enable_debug"
276 echo
277 echo "Additional Plugins:"
278 echo
279 echo "* Advanced Properties:                $ac_bm_thunar_plugin_apr"
280 echo "* Simple Builtin Renamers:            $ac_bm_thunar_plugin_sbr"
281 echo "* Trash Panel Applet:                 $ac_bm_thunar_plugin_tpa"
282 echo "* User Customizable Actions:          $ac_bm_thunar_plugin_uca"
283 echo "* Wallpaper support:                  $ac_bm_thunar_plugin_wallpaper"
284 echo